**SNL**语言的上下文无关文法

**总程序：**

1) Program ::= ProgramHead DeclarePart ProgramBody **.**

程序头：

2) ProgramHead ::= **PROGRAM** ProgramName

3) ProgramName ::= **ID**

程序声明：

4) DeclarePart ::= TypeDecpart VarDecpart ProcDecpart

类型声明：

5) TypeDecpart ::= ε

6) | TypeDec

7) TypeDec ::= **TYPE** TypeDecList

8) TypeDecList ::= TypeId **=** TypeDef **;** TypeDecMore

9) TypeDecMore ::= ε

10) | TypeDecList

11) TypeId ::= **ID**

类型：

12) TypeDef ::= BaseType

13) | StructureType

14) | **ID**

15) BaseType ::= **INTEGER**

16) | **CHAR**

17) StructureType ::= ArrayType

18) | RecType

19) ArrayType ::= **ARRAY [**low**..**top **] OF** BaseType

20) Low ::= **INTC**

21) Top ::= **INTC**

22) RecType ::= **RECORD** FieldDecList **END**

23) FieldDecList ::= BaseType IdList **;** FieldDecMore

24) | ArrayType IdList **;** FieldDecMore

25) FieldDecMore ::= ε

26) | FieldDecList

27) IdList ::= **ID** IdMore

28) IdMore ::= ε

29) | **,** IdList

变量声明：

30) VarDecpart ::= ε

31) | VarDec

32) VarDec ::= **VAR** VarDecList

33) VarDecList ::= TypeDef VarIdList **;** VarDecMore

34) VarDecMore ::= ε

35） | VarDecList

36）VarIdList ::= **ID** VarIdMore

37）VarIdMore ::= ε

38） | **,** VarIdList

过程声明：

39) ProcDecpart ::= ε

40) | ProcDec

41) ProcDec ::= **PROCEDURE**

ProcName **(** ParamList **) ;**

ProcDecPart

ProcBody

ProcDecMore

42) ProcDecMore ::= ε

43) | ProcDeclaration

44) ProcName ::= **ID**

参数声明：

45) ParamList ::= ε

46) | ParamDecList

47) ParamDecList ::= Param ParamMore

48) ParamMore ::= ε

49) | **;** ParamDecList

50) Param ::= TypeDef FormList

51) | **VAR** TypeDef FormList

52) FormList ::= **ID** FidMore

53) FidMore ::= ε

54) | **,** FormList

过程中的声明部分：

55) ProcDecPart ::= DeclarePart

过程体：

56) ProcBody ::= ProgramBody

主程序体：

57) ProgramBody ::= **BEGIN** StmList **END**

语句序列：

58) StmList ::= Stm StmMore

59) StmMore ::= ε

60) | **;** StmList

语句：

61) Stm ::= ConditionalStm

62) | LoopStm

63) | InputStm

64) | OutputStm

65) | ReturnStm

66) | ID AssCall

67) AssCall ::= AssignmentRest

68) | CallStmRest

赋值语句：

69) AssignmentRest ::= VariMore **:=** Exp

条件语句：

70) ConditionalStm ::= **IF** RelExp **THEN** StmList **ELSE** StmList **FI**

循环语句：

71) LoopStm ::= **WHILE** RelExp **DO** StmList **ENDWH**

输入语句：

72) InputStm ::= **READ (** Invar**)**

73) Invar ::= **ID**

输出语句：

74) OutputStm ::= **WRITE(** Exp **)**

返回语句：

75) ReturnStm ::= **RETURN**

过程调用语句：

76) CallStmRest ::= **(** ActParamList **)**

77) ActParamList ::= ε

78) | Exp ActParamMore

79) ActParamMore ::= ε

80) | **,** ActParamList

条件表达式：

81) RelExp ::= Exp OtherRelE

82) OtherRelE ::= CmpOp Exp

算术表达式：

83) Exp ::= Term OtherTerm

84) OtherTerm ::= ε

85) | AddOp Exp

项：

86) Term ::= Factor OtherFactor

87) OtherFactor ::= ε

88) | MultOp Term

因子：

89) Factor ::= **(** Exp **)**

90) | **INTC**

91) | Variable

92) Variable ::= **ID** VariMore

93) VariMore ::= ε

94) | **[** Exp **]**

95) | **.** FieldVar

96) FieldVar ::= **ID** FieldVarMore

97) FieldVarMore ::= ε

98) | **[** Exp **]**

99) CmpOp ::= **<**

100) | **=**

101)AddOp ::= +

102) | **-**

103) MultOp ::= **\***

104） | **/**